Numlock ein/aus mit VBA

Hallo Helmut,

erneut danke fur deine Frage. Da es sich hier um ein VBA Anliegen handelt, darf ich dich bitten, einen Beitrag in der MSDN Community zu verfassen und dort deinen Fall zu schildern.

Wir haben nur begrenzt Möglichkeiten, Dir zu helfen und in der Community helfen viele Microsoft Moderatoren, die andere Mittel haben, um Dir bei der Lösung des Problems behilflich zu sein.

In diesem Link klicke bitte oben links auf Eine Frage stellen.

Wenn du noch andere Fragen hast oder wieder Hilfe brauchst, lass es uns bitte wissen.

MfG

Bernard

Hi,

"Wie kann ich diese Eigenschaft unter VBA für Excel abfragen?"

Public Const VK_NUMLOCK = &H90

Public Declare Function GetKeyState Lib "user32" _

(ByVal nVirtKey As Long) As Long

Sub Status_numlock()

Debug.Print "Numlock ist " & IIf(GetKeyState(VK_NUMLOCK) = 1, "AN", "Aus")

End Sub

Code in einem allgemeinen Modul.

Numlock setzten würde aufwendiger sein!

Hast du im Moment welche Sendkeys im Einsatz?

Selbige machen zumeist Probleme und sollten vermieden werden.

lg

Chris

Option Explicit

#If Win64 Then

Private Declare PtrSafe Sub keybd_event Lib "user32" ( _

ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, _

ByVal dwExtraInfo As LongPtr)

Private Declare PtrSafe Function GetKeyboardState Lib "user32" ( _

pbKeyState As Byte) As Long

#Else

Private Declare Sub keybd_event Lib "user32" ( _

ByVal bVk As Byte, ByVal bScan As Byte, ByVal dwFlags As Long, ByVal dwExtraInfo As Long)

Private Declare Function GetKeyboardState Lib "user32" (pbKeyState As Byte) As Long

#End If

Private Const VK_NUMLOCK = &H90

Private Const VK_SCROLL = &H91

Private Const VK_CAPITAL = &H14

Private Const KEYEVENTF_EXTENDEDKEY = &H1

Private Const KEYEVENTF_KEYUP = &H2

Property Get NumLock() As Boolean

Dim Keys(0 To 255) As Byte

GetKeyboardState Keys(0)

NumLock = Keys(VK_NUMLOCK)

End Property

Property Let NumLock(Value As Boolean)

Dim Keys(0 To 255) As Byte

GetKeyboardState Keys(0)

If Value <> CBool(Keys(VK_NUMLOCK)) Then

keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0

keybd_event VK_NUMLOCK, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0

End If

End Property

Property Get CapsLock() As Boolean

Dim Keys(0 To 255) As Byte

GetKeyboardState Keys(0)

CapsLock = Keys(VK_CAPITAL)

End Property

Property Let CapsLock(Value As Boolean)

Dim Keys(0 To 255) As Byte

GetKeyboardState Keys(0)

If Value <> CBool(Keys(VK_CAPITAL)) Then

keybd_event VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0

keybd_event VK_CAPITAL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0

End If

End Property

Property Get ScrollLock() As Boolean

Dim Keys(0 To 255) As Byte

GetKeyboardState Keys(0)

ScrollLock = Keys(VK_SCROLL)

End Property

Property Let ScrollLock(Value As Boolean)

Dim Keys(0 To 255) As Byte

GetKeyboardState Keys(0)

If Value <> CBool(Keys(VK_SCROLL)) Then

keybd_event VK_SCROLL, &H45, KEYEVENTF_EXTENDEDKEY Or 0, 0

keybd_event VK_SCROLL, &H45, KEYEVENTF_EXTENDEDKEY Or KEYEVENTF_KEYUP, 0

End If

End Property

Was ist "der rechte Teil der Tastatur" (Nummernblock oder Buchstabentasten für die rechte Hand) und was hat das mit Word zu tun?

Meinst Du "NumLock"? Wenn es das nicht ist, hat Deine Tastatur wohl eine Fehlfunktion.

Gruß

G.O.

Hallo,

eventuell liegt dies an einem installierten Add-In oder einem Makro.

Starte Excel im abgesicherten Modus, in dem du die Strg-Taste drückst und während des Starts von Excel gedrückt hälst. Ändert sich anschließend der Zustand der Numlock-Taste nicht, ist meine Vermutung bestätigt und du musst herausfinden welches Add-In oder
welcher VBA-Code das Verhalten hervorruft.



Mit freundlichem Gruß aus der Rattenfängerstadt Hameln



(www.at-exceltraining.de)


Ist deine Frage mit diesem Beitrag beantwortet, markiere sie für alle Mitleser als Antwort
. (Du kannst auch mehrere Beiträge als Antwort markieren)