Excel 2016: Per VBA den Ausgangswert einer Operation mit dem Ergebnis überschreiben

Hallo Philipp,

probiere mal:

Sub Ersetzen()

Dim LRow1 As Long, LRow2 As Long

Dim i As Long

Dim varCheck As Variant
'Hier den Bereich und den Blattnamen

'für die Tabelle mit den Zuordnungen anpassen

With Sheets("Tabelle2")

   LRow2 = .Cells(.Rows.Count, "A").End(xlUp).Row

   varCheck = .Range("A1:B" & LRow2)

End With

'Hier den Bereich und den Blattnamen

'für die Haupttabelle anpassen

With Sheets("Tabelle1")

   LRow1 = .Cells(.Rows.Count, "C").End(xlUp).Row

   For i = LBound(varCheck) To UBound(varCheck)

      .Range("C1:C" & LRow1).Replace what:=varCheck(i, 1), _

         replacement:=varCheck(i, 2), MatchCase:=True

   Next

End With

End Sub

Claus

Hallo Claus,

das ging aber schnell und - funktioniert perfekt!!

Genauso, wie ich mir das bestenfalls erhofft habe

Vielen lieben Dank noch mal dafür!

Grüße, Philipp

Hallo Claus,

funktioniert nach Anpassung der Blattnamen auf Anhieb perfekt! Cool, bist echt ein Profi - vielen Dank dafür!

Durch den gegebenen Aufbau der Tabellen wären noch folgende Detailanpassungen nötig. Kurz ein Beispiel zum Aufbau der Daten:

Tabelle1

Spalte C (Bearbeiter), C2 = 00524000007yHoeAAE

Tabelle2

Spalte A (Benutzer-ID), A2 = 00524000007yHoe

Spalte B (Vorname), B2 = Max

Spalte C (Nachname), C2 = Muster

Meine Wünsche:

1. Vor- und Nachnamen sollen zu 'Max Muster' verkettet in Tabelle1 geschrieben werden (im Moment wird nur der Vornamen übernommen)

2. Die Benutzer-ID ist in Tabelle1 um drei (irrelevante) Zeichen länger als die in Tabelle2. Das führt im Beispiel zum Ergebnis 'MaxAAE'. Wie lassen sich die letzten drei Zeichen unterdrücken?

3. Tatsächlich ist die Spaltenreihenfolge in Tabelle2 etwas anders, was die Position der Benutzer-ID betrifft:

Tabelle2

Spalte A (Vorname), A2 = Max

Spalte B (Nachname), B2 = Muster

Spalte C (Benutzer-ID), C2 = 00524000007yHoe

(zum Test hatte die B-ID in Spalte A verschoben) Käme VBA auch mit diesem Aufbau klar?

Da Tabelle2 gelegentlich durch eine aktuelle Fassung ersetzt wird, würde ich die nicht jedes Mal anpassen wollen, wenn es eine VBA-Lösung gäbe.

Danke & Grüße, Philipp

Hallo Andreas,

danke für die schnelle Antwort!

Aus verschiedenen Gründen will ich keine zusätzlichen Spalten einfügen. U.a., weil auch andere Personen mit der Datei arbeiten sollen und erfahrungsgemäß die Gefahr der Fehlbedienung besteht;-(

In Sachen VBA habe ich im Vorfeld gegoogelt, wie andere Anwender ähnliche
Probleme lösen. Deshalb habe ich eine ungefähre Vorstellung, nur sind deren Lösungen nicht wirklich übertragbar. Vielleicht könnte ich es mir auch selber erarbeiten, aber das wäre ein steiniger Weg! Deshalb hoffe ich auf eine kleine Hilfestellung der Excel-Profis.

Die Datei will ich wg. sensibler Daten ungern bereitstellen. Ob ein anonymisierter Inhalt noch für die Problemlösung taugt, kann ich jetzt nicht beurteilen. Ich hoffe Du verstehst das.

Bei Bedarf könnte ich aber die Formel posten, die ich zu Testzwecken zur Ausführung aus einer Zelle heraus erstellt habe (ist noch nicht ganz final, da noch eine Rahmenfrage offen ist).

Grüße, Philipp

Hallo Philipp,

dann probiere mal:

Sub Ersetzen()

Dim LRow1 As Long, LRow2 As Long

Dim i As Long

Dim varCheck As Variant

Dim c As Range

Dim FirstAddress As String

'Hier den Bereich und den Blattnamen

'für die Tabelle mit den Zuordnungen anpassen

With Sheets("Tabelle2")

   LRow2 = .Cells(.Rows.Count, "A").End(xlUp).Row

   varCheck = .Range("A2:C" & LRow2)

End With

'Hier den Bereich und den Blattnamen

'für die Haupttabelle anpassen

With Sheets("Tabelle1")

   LRow1 = .Cells(.Rows.Count, "C").End(xlUp).Row

   For i = LBound(varCheck) To UBound(varCheck)

      Set c = .Range("C1:C" & LRow1).Find(varCheck(i, 3), LookIn:=xlValues, _

         lookat:=xlPart, MatchCase:=True)

      If Not c Is Nothing Then

         Do

            c = varCheck(i, 1) & " " & varCheck(i, 2)

            Set c = .Range("C1:C" & LRow1).FindNext(c)

         Loop While Not c Is Nothing

      End If

   Next

End With

End Sub

Sollte dies nicht funktionieren, poste mal ein paar mehr Beispiele, damit wir sehen können wie es sich mit den angehängten Zeichen und der Groß- bzw. Kleinschreibung verhält.

Claus