Excel 365 Formular erstellen

Hallo,

das ist in Excel auf diesem Weg nicht möglich.

Wenn diese Formular nur der Eingabe dient (keine Berechnung), dann erstelle dieses Formular in Word und füge an den entsprechenden Stellen Textbausteine ein.

Wenn du es unbedingt in Excel machen musst, erstelle eine Eingabemaske, indem du eine Userform mit den entsprechenden Textfeldern erstellst und diese Eingaben dann bei Klick auf den Button zur Übernahme in die entsprechenden Zellen eingetragen werden.

Claus

Hallo Andreas, danke für prompte Hilfe! Ich werde mir das genau anschauen, weil ich das auch verstehen möchte. Momentan sind da noch n paar böhmische Dörfer drin...Ich hoffe du steht's mir ggf auch für Rückfragen zur Verfügung?!
<br />

Ich hoffe du steht's mir ggf auch für Rückfragen zur Verfügung?!

Hallo Christine,
<br />Naja, dafür bin ich hier. Und solange es nicht in einen Grundkurs VBA ausartet... 😊
<br />Andreas.
<br />

1. Auswahlvorgabe für Spalte A ist Ja/Nein2. Spalten B und C können nur bearbeitet werden wenn A=Ja3. Spalten B und C sind entweder leer oder entweder B=X ODER C=X4. Der Absolute Hit wäre, wenn wechselseitig der Eintrag des X in den Spalten B und C zum Löschen des Inhaltes der jeweils anderen Spalte führt.

Das geht nur mit VBA.
<br />Klicke mit der rechten Maustaste auf die Blattregisterkarte
Wähle "Code anzeigen"
Füge den folgenden Code ein
Schließe den VBA-Editor

<br />Andreas.
<br />Option Explicit
Option Compare Text

Private Sub Worksheet_Change(ByVal Target As Range)
Dim A As Range
'Uns interessiert nur A:C im benutzten Bereich
Set Target = Intersect(Target, Range("A:C"), Me.UsedRange)
If Target Is Nothing Then Exit Sub
'Die Logik funktioniert nur wenn nur eine Zelle geändert wird
If Target.Count > 1 Then Exit Sub
'Ereignisse aus, sonst rufen wir uns selber auf
Application.EnableEvents = False
'In welcher Spalte wurde geändert?
Select Case Target.Column
Case 1 'Spalte A
'Welchen Wert hat die Zelle?
Select Case Target.Value
Case "Ja", "Nein", Empty
'Ok weil Ja, Nein oder leer
Case Else
'Vorherigen Wert wieder herstellen
Application.Undo
MsgBox "Nur 'Ja' oder 'Nein' erlaubt!", vbExclamation
End Select
Case 2, 3
'Spalte B,C
Set A = Range("A" & Target.Row)
If A.Value <> "Ja" Then
Application.Undo
MsgBox "Bearbeitung nicht erlaub weil " & A.Address(0, 0) & " nicht 'Ja' ist!", vbInformation
Else
'Die andere Zelle referenzieren
If Target.Column = 2 Then
Set A = Range("C" & Target.Row)
Else
Set A = Range("B" & Target.Row)
End If
'Welchen Wert hat die Zelle?
Select Case Target.Value
Case Empty
'Leer is ok
Case "X"
'Die andere Zelle leeren
A.ClearContents
Case Else
Application.Undo
MsgBox "Es ist nur ein 'X' erlaubt!", vbExclamation
End Select
End If
End Select
'Ereignisse an
Application.EnableEvents = True
End Sub

<br />

Über die App Microsoft Forms kannst Du ein (Online-)Formular erstellen, dessen Ergebnisse dann in einer Excel-Datei gespeichert werden. Vielleicht wäre das eine Alternative zu einem Arbeitsblatt mit Formular-Steuerelementen?
<br />Viele Grüße
<br />Ute
<br />