Excel 365 version 1906 introduces bug in .OnAction callbacks with arguments

Since Version 1906 of Excel 365 clicking on Shapes that have their .OnAction property set to a callback procedure with arguments will do no callback to the procedure but will show an ominous error message instead.

This problem has been reproduced by multiple customers of mine. Reverting Office to the last build of version 1905 seems to fix the issue.

I did some testing and realized that callbacks with no arguments will work, but the ones with arguments are broken.

I did not test if the .OnAction properties of other classes like CommandBarControls and Form Controls are affected as well, but I assume they are.

I added a screenshot of the (german) event log error description and some testing code that exemplifies the problem.




'Copy the following code into an Excel VBA module called 'modTest'.
'Run the CreateTestSheet() sub in order to create the test sheet.
'On the sheet there will be 3 shapes. Click on each once to see which callbacks work and which don't.

Option Explicit

Private Sub CreateTestSheet()
'will create a sheet with 3 shapes that exemplify the problem
'all the callbacks worked in Excel prior to XL365 Version 1906, but the ones with arguments are broken now

On Error GoTo err

Dim cSheet As Excel.Worksheet
Dim strSheetName As String
Dim cShape As Excel.Shape

strSheetName = "bug1906"

Application.DisplayAlerts = False
On Error Resume Next
Set cSheet = ThisWorkbook.Worksheets(strSheetName)
cSheet.Delete
On Error GoTo err
Application.DisplayAlerts = True

Set cSheet = ThisWorkbook.Worksheets.Add
cSheet.Name = strSheetName
cSheet.Activate

'1 does work, due to no arguments being used
Set cShape = cSheet.Shapes.AddShape(msoShapeRectangle, 30, 20, 100, 50)
With cShape
cShape.TextFrame2.TextRange.Text = "1: works"
.OnAction = "'modTest.XlControlCallback1'"
End With

'2: the most simple example of what doesn't work
Set cShape = cSheet.Shapes.AddShape(msoShapeRectangle, 30, 90, 100, 50)
With cShape
cShape.TextFrame2.TextRange.Text = "2: does not work"
.OnAction = "'modTest.XlControlCallback2 """ & "str1" & """'"
End With

'3: a more complex example of what doesn't work
Set cShape = cSheet.Shapes.AddShape(msoShapeRectangle, 30, 160, 100, 50)
With cShape
cShape.TextFrame2.TextRange.Text = "3: does not work either"
.OnAction = "'modTest.XlControlCallback3 """ & 1 & """,""" & "str1" & """,""" & "opt str2" & """'"
End With

Exit Sub
err:
Debug.Print err.Number, err.Description
End Sub

Public Sub XlControlCallback1()

On Error GoTo err

Debug.Print "XlControlCallback1"

Exit Sub
err:
Debug.Print err.Number, err.Description
End Sub

Public Sub XlControlCallback2(strId1 As String)

On Error GoTo err

Debug.Print "XlControlCallback2", strId1

Exit Sub
err:
Debug.Print err.Number, err.Description
End Sub

Public Sub XlControlCallback3(lngType As Long, strId1 As String, Optional strId2 As String)

On Error GoTo err

Debug.Print "XlControlCallback3", lngType, strId1, strId2

Exit Sub
err:
Debug.Print err.Number, err.Description
End Sub