Individuelle Formatierte Bedingung in geschlossener Mappe

Leider hat dies meine Frage nicht beantwortet.
Ich möchte eine Zelle bedingt formatieren, dass habe ich auch gemacht.
Stand jetzt:
20 kurzlaute (F;S;N;T;BF;BS;BN;BT;S/F;N/F;…..)
Diese können durch Vorgabe mit je 32 Farben in Schrift, 32 Farben im Hintergrund, FETT, unterstrichen, Kursiv oder und auch durchgestrichen ausgewählt werden.
Jetzt möchte ich den Farbbereich aber endlich machen (für Schrift und Hintergrund je Zelle)
Über bedingter Formatierung, bin ich entweder eingeschränkt oder das System stirbt fast)
Wichtig ist auch, dass diese Funktion auch im gesperrten Modus funktionieren muss.

ich möchte in der Zelle B100 „F“, in Zelle B101 „S“, … ,individuell über das gegebene Toll einfärben (Schrift und Hintergrund), sowie kursiv, Fett, unterstrichen und durchgestrichen einsetzen können, was im Bereich A1:BA50 als Formatierter Bedingung übernommen werden soll.wenn jede einzelne Zelle aus dem Bereich A1:BA50 die Zellenformation aus B100, B101, … herausholt, wie es in einer vorgegebenen Zelle dargestellt wird

Wenn wir mal annehmen das in B100 ein "F" steht was blau ist und in B101 ein "S" steht was rot ist und in A1 steht nun "FS", dann soll das F blau werden und das S rot!?
a) Es ist nicht möglich verschiedene Hintergrundfarben in einer Zelle zu haben.
b) Es ist nicht möglich einen Teil eines Textes "einzufärben" wenn die Zelle eine Formel enthält.
c) Wir brauchen noch eine Zelle die das Standardformat enthält, ich nehme mal B99




Mache eine neue Datei
Schreib mind. in B100 was rein und formatiere es
Klicke mit der rechten Maustaste auf die Blattregisterkarte
Wähle "Code anzeigen"
Füge den folgenden Code ein
Schließe den VBA-Editor

Andreas.
Option Explicit

Private Sub Worksheet_Change(ByVal Target As Range)
Dim Where As Range, W As Range
Dim Formats As Range, F As Range
Dim i As Long, j As Long
Dim Props, Prop, Value
Props = Array("Bold", "Color", "FontStyle", "Italic", "Name", "Size", "Strikethrough", "Subscript", "Superscript", "Underline")

If Intersect(Target, Range("A1:BA50")) Is Nothing Then Exit Sub
Application.EnableEvents = False
Range("B99").Copy
Target.PasteSpecial xlPasteFormats
Application.CutCopyMode = False
Set Formats = Range("B100").CurrentRegion
For Each F In Formats
Set Where = FindAll(Target, F, , xlValues, xlPart)
If Not Where Is Nothing Then
For Each W In Where
i = InStr(1, W.Value, F.Value, vbTextCompare)
Do While i > 0
For j = 1 To Len(F.Value)
For Each Prop In Props
Value = VBA.CallByName(F.Characters(j, 1).Font, Prop, VbGet)
VBA.CallByName W.Characters(i + j - 1, 1).Font, Prop, VbLet, Value
Next
Next
i = InStr(i + 1, W.Value, F.Value, vbTextCompare)
Loop
Next
End If
Next
Application.EnableEvents = True
End Sub

Function FindAll(ByVal Where As Range, ByVal What, _
Optional ByVal After As Variant, _
Optional ByVal LookIn As XlFindLookIn = xlValues, _
Optional ByVal LookAt As XlLookAt = xlWhole, _
Optional ByVal SearchOrder As XlSearchOrder = xlByRows, _
Optional ByVal SearchDirection As XlSearchDirection = xlNext, _
Optional ByVal MatchCase As Boolean = False, _
Optional ByVal SearchFormat As Boolean = False) As Range
'Find all occurrences of What in Where (Windows version)
Dim FirstAddress As String
Dim C As Range
'From FastUnion:
Dim Stack As New Collection
Dim Temp() As Range, Item
Dim i As Long, j As Long

If Where Is Nothing Then Exit Function
If SearchDirection = xlNext And IsMissing(After) Then
'Set After to the last cell in Where to return the first cell in Where in front if _
it match What
Set C = Where.Areas(Where.Areas.Count)
'BUG in XL2010: Cells.Count produces a RTE 6 if C is the whole sheet
'Set After = C.Cells(C.Cells.Count)
Set After = C.Cells(C.Rows.Count * CDec(C.Columns.Count))
End If

Set C = Where.Find(What, After, LookIn, LookAt, SearchOrder, _
SearchDirection, MatchCase, SearchFormat:=SearchFormat)
If C Is Nothing Then Exit Function

FirstAddress = C.Address
Do
Stack.Add C
If SearchFormat Then
'If you call this function from an UDF and _
you find only the first cell use this instead
Set C = Where.Find(What, C, LookIn, LookAt, SearchOrder, _
SearchDirection, MatchCase, SearchFormat:=SearchFormat)
Else
If SearchDirection = xlNext Then
Set C = Where.FindNext(C)
Else
Set C = Where.FindPrevious(C)
End If
End If
'Can happen if we have merged cells
If C Is Nothing Then Exit Do
Loop Until FirstAddress = C.Address

'FastUnion algorithm © , 2011:
'Get all cells as fragments
ReDim Temp(0 To Stack.Count - 1)
i = 0
For Each Item In Stack
Set Temp(i) = Item
i = i + 1
Next
'Combine each fragment with the next one
j = 1
Do
For i = 0 To UBound(Temp) - j Step j * 2
Set Temp(i) = Union(Temp(i), Temp(i + j))
Next
j = j * 2
Loop Until j > UBound(Temp)
'At this point we have all cells in the first fragment
Set FindAll = Temp(0)
End Function

Hola,
mit der bedingten Formatierung kannst du keine Formate aus anderen Zellen auslesen und übernehmen.
Eventuell ginge das über VBA. Allerdings klingt das auch eher nach Auftragsarbeit.
Gruß,

Hallo, ich bin Leonielhou, ein unabhängiger Berater und ein Benutzer wie Sie, ich helfe gerne bei der Klärung Ihrer Fragen.

Um einzelne Zellen in einem Bereich in Microsoft Office einzufärben, können Sie die Option "Füllfarbe" in der Gruppe "Schriftart" der Registerkarte "Start" in der Multifunktionsleiste verwenden.

Um die Formatierung auf mehrere Zellen gleichzeitig anzuwenden, können Sie den Zellbereich auswählen, den Sie formatieren möchten, und dann die Optionen in der Gruppe "Schriftart" verwenden, um die gewünschte Formatierung anzuwenden.

Wenn Sie die Formatierung basierend auf dem Inhalt einer bestimmten Zelle anwenden möchten, können Sie die bedingte Formatierung verwenden. Wählen Sie dazu den Zellbereich aus, auf den Sie die Formatierung anwenden möchten, gehen Sie dann zur Registerkarte "Startseite" und klicken Sie in der Gruppe "Stile" auf die Schaltfläche "Bedingte Formatierung". Dadurch wird das Fenster "Bedingte Formatierung" geöffnet, in dem Sie Regeln für die Formatierung basierend auf dem Inhalt der Zellen einrichten können.

Es ist auch möglich, eine Formel im Feld "Werte formatieren, bei denen diese Formel wahr ist" zu verwenden, um Formatierungen basierend auf dem Inhalt anderer Zellen anzuwenden. Sie können z. B. die Formel "=B100="F"" verwenden, um Zellen im ausgewählten Bereich zu formatieren, wenn die Zelle in B100 den Wert "F" enthält.

Ich hoffe, dass ich auf der Grundlage dessen, was ich über Ihr Anliegen verstanden habe, wertvolle Informationen geben kann.

Diese Antwort ist automatisch übersetzt worden. Daher kann sie grammatikalische Fehler oder fremde Ausdrücke enthalten.

Leider hat dies meine Frage nicht beantwortet.

Doch, das hat es, Du hast es nur noch nicht realisiert. ;-) Ist ganz einfach:
20 Kurzlaute * 32 Farben * 32 Hintergrundfarben * 2 (Fett oder nicht) * 2 (unterstrichen oder nicht) * 2 (Kursiv oder nicht) * 2 (durchgestrichen oder nicht) =20*32*32*2*2*2*2 = 327680 verschiedene bedingte Formatierungen pro Zelle.
Wenn wir das auf 100 Zellen anwenden kommen wir auf über 32 Millionen Formeln die Excel berechnen muss bis Dein Blatt schön bunt geworden ist. Du hast aber A1:BA50 was 50*53 =2650 Zellen sind...
Wie auch immer genau die Anzahl der Formeln ist die Du aktuell verwendest, es ist wohl klar das es so nicht geht.
Ansonsten würdest Du diese Frage ja nicht stellen. .-)
Die Menge an Formeln zwingt das System in die Knie. Ergo: Das geht nicht, ein anderer Weg muss her.
Ich mache für diese Fälle ein Setup Blatt in die Datei und da kann man dann die Kürzel reinschreiben und entsprechend formatieren und der VBA-Code formatiert dann die Zellen im Planer. Ein Kürzel=Ein Format.
Mein Code oben unterstützt verschiedene Kürzel pro Zelle, was die Hintergrundfarbe ausschließt. Wenn man es auf ein Kürzel pro Zelle vereinfacht, dann gehen auch Hintergrundfarben.
Das funktioniert gut und die vielen bunten Zellen blähen die Datei nur mäßig auf. Und je größer die Datei, desto langsamer wird sie, schön bunt dauert halt.
Dann kommen wir zum letzten Punkt: Es muss so oder so und überall funktionieren... was auch immer der gesperrte Modus sein soll: Eine VBA-Lösung funktioniert nur dort wo VBA funktioniert, nicht Online, nicht auf dem Handy...
Wenn Dir das alles nicht gefällt, dann läßt sich Dein Vorhaben halt nicht mit Excel realisieren und Du musst Dir die passende Planungssoftware kaufen, welche auch immer das ist.
Andreas.