Anstehende Aufgaben MS Project 2013

Hallo,

vielen Dank für die Antwort!

Leider hilft sie mir noch nicht ganz weiter. Meine Aufgaben sind oft nur wenige Minuten oder Stunden lang und deshalb reicht mir eine Filterung nach Datum nicht aus.

Wichtig wäre mir ein Filter für alle Aufgaben, deren Vorgänger abgeschlossen sind bzw. deren festdefinierte Startzeiten erreicht sind. Eine automatisch aktualisierte To Do Liste. Eigentlich sollte das doch einfach erkennbar sein.

Viele Grüße

Jörg

Hallo Barbara,

wow, vielen Dank!

Es hat leider etwas länger gedauert, bis ich antworten konnte.

Das Makro funktioniert genau so, wie es soll. Vielleicht schafft es die Funktion ja auch irgendwann in den Standard - mir erleichtert es die Nutzung im Projekt auf jeden Fall sehr.

Nochmal vielen, vielen Dank!

Jörg

Hallo,

das wäre das Makro. Ich setze hier Attribut1 auf "Ja", wenn alle Vorgänger abgeschlossen sind oder das Startdatum vor heute+7Tage liegt. Sowohl das Feld als auch der Zeitabstand lassen sich ändern.

Sub CurrentTasks()

'https://answers.microsoft.com/de-de/msoffice/forum/all/anstehende-aufgaben-ms-project-2013/bb0b66cd-573d-4d8b-9cca-2b8e80bcd53f

'This macro will set a flag field to True, if all predecessors are completed or start date is before actual date + a defined period

'Flag Field to be used. Please use always "Flag", code is not using language dependent field names

Const c_FlagField = "Flag1"

'Set value for x days in future (not working days!!!)

Const c_FutureDays = 7

Dim P As Project

Dim T As Task

Dim PT As Task

Dim v_FlagField As Double

Dim v_CFTrue As String

Dim v_CFFalse As String

Set P = ActiveProject

'Get internal field ID

v_FlagField = Application.FieldNameToFieldConstant(c_FlagField, pjTask)

'To be language independent, we need to get text for true and false

'Set formula with result True and write to variable v_CFTrue

Application.CustomFieldSetFormula FieldID:=v_FlagField, Formula:="1=1"

CustomFieldPropertiesEx FieldID:=v_FlagField, Attribute:=pjFieldAttributeFormula, SummaryCalc:=pjCalcFormula, GraphicalIndicators:=False

v_CFTrue = P.ProjectSummaryTask.GetField(v_FlagField)

'Set formula with result False and write to variable v_CFFalse

Application.CustomFieldSetFormula FieldID:=v_FlagField, Formula:="1=0"

Application.CustomFieldPropertiesEx FieldID:=v_FlagField, Attribute:=pjFieldAttributeFormula, SummaryCalc:=pjCalcFormula, GraphicalIndicators:=False

v_CFFalse = P.ProjectSummaryTask.GetField(v_FlagField)

'Remove formula from field

Application.CustomFieldDelete (v_FlagField)

For Each T In P.Tasks

If Not T Is Nothing Then

'Initialize flag with False

T.SetField FieldID:=v_FlagField, Value:=v_CFFalse

'If there are any predecessors, we need to check completion, as long as task is not yet completed

If T.PredecessorTasks.Count > 0 And T.PercentComplete <> 100 Then

'Initalize field in this case with True, to set False if there are incomplete predecessors

T.SetField FieldID:=v_FlagField, Value:=v_CFTrue

'Check all predecessors

For Each PT In T.PredecessorTasks

' if there is any incomplete predecessor, set flag to false

If PT.PercentComplete < 100 Then

T.SetField FieldID:=v_FlagField, Value:=v_CFFalse

End If

Next PT

Else

'If there are no predecessors, we want to flag task if should have been started

If DateSerial(Year(T.Start), Month(T.Start), Day(T.Start)) <= DateAdd("d", c_FutureDays, Date) And T.PercentComplete <> 100 Then

T.SetField FieldID:=v_FlagField, Value:=v_CFTrue

End If

End If

End If

Next T

End Sub

Viele Grüße

Barbara

Hallo,

diese Funktion bietet Project leider nicht. Es gibt keine Filterfunktionen, die Eigenschaften von Vorgängern oder Nachfolgern prüfen. Mit einem Makro könnte man vermutlich ein Attributfeld für die Bedingungen setzen. Das müsste ich mir aber irgendwann in
Ruhe ansehen. Wäre ein Makro eine Option?

Viele Grüße

Barbara Henhapl

Hallo,

wenn der Projektplan einigermaßen aktuell gehalten wird, also auch ein Endedatum bei früherem oder späteren Ende korrigiert wird, lässt sich das mit einer Standardfunktion umsetzen.

Wenn der Fortschritt für alle Vorgänge eingetragen ist und der Endtermin bei Bedarf angepasst wurde, kann die Arbeit, die noch in der Vergangenheit fällig gewesen wäre, entsprechend in die Zukunft schieben (Projekt - Projekt aktualisieren - Arbeit nicht
abgeschlossener Vorgänge verschieben auf Datum nach):





Dann kann mit dem Filter "Terminbereich" aud die Vorgänge eines Zeitraums gefiltert werden. Ich verwende hier 7.1.-13.1.2019:





In dieser Woche muss "a" abgeschlossen und "b" angefangen werden.

Hilft das?

Viele Grüße

Barbara