Automatische Kopfzeile für alle (zukünftigen) Tabellen

Vielen Dank, dass hat mein Problem gelöst!

Ich beschreibe noch einmal kurz den Lösungsansatz den ich verfolgt habe:

• In den "Excel-Optionen" die Registerkarte "Entwickler-Tools" aktivieren.
• Unter "Ansicht -> Einblenden" die "PERSONAL" Arbeitsmappe einblenden lassen. Gibt es diese noch nicht, unter "Entwickler-Tools -> Makro aufzeichnen" eine Aufnahme in "persönliche Arbeitsmappe" starten und ggf. sofort wieder beenden.
  
• Den VBA-Editor öffnen (Registerkarte Entwickler-Tools -> "Visual Basic")
• Doppelklick auf "DieseArbeitsmappe" der Datei "PERSONAL.XLSB"
• Ich habe den Code von Herrn Andreas Killer dahingehend verändert, dass alle Tabellen einer neu erstellten Arbeitsmappe bzw. neu erstellte Tabellen in allen Arbeitsmappen eine im Makro festgelegte Kopf- und Fußzeile erhalten.

Hier der Code:

Option Explicit



Dim WithEvents App As Application



' Iteriert über alle Tabellen und konfiguriert die Kopf- und Fußzeile

Private Sub App_NewWorkbook(ByVal Wb As Workbook)

Dim WS_Count As Integer

Dim I As Integer



WS_Count = Wb.Worksheets.Count



For I = 1 To WS_Count

With Wb.Worksheets(I).PageSetup

.LeftHeader = "&F - &A"

.RightHeader = "&D - &T"

.RightFooter = "Seite &P von &N"

End With

Next I

End Sub



' Konfiguriert die Kopf- und Fußzeile der neuen Tabelle

Private Sub App_WorkbookNewSheet(ByVal Wb As Workbook, ByVal Sh As Object)

With Sh.PageSetup

.LeftHeader = "&F - &A"

.RightHeader = "&D - &T"

.RightFooter = "Seite &P von &N"

End With

End Sub



Private Sub Workbook_Open()

Set App = Application

End Sub

• Nun noch speichern und Excel beenden
  

Mit freundlichen Grüßen

Ich beschreibe noch einmal kurz den Lösungsansatz den ich verfolgt habe:

Sehr gut umgesetzt, freut mich das ich helfen konnte.

Andreas.

Ist es auch möglich ein Makro an das Erstellen einer Tabelle zu knüpfen? Ansonsten würden neu hinzugefügte Tabellen nicht automatisch eine Kopfzeile erhalten.

Ja, das geht, ist allerdings für Anfänger sehr "undurchsichtig" und schwierig zu verstehen das abläuft.

Ich rate davon ab. Es ist einfacher das Makro bei Bedarf einmal "von Hand" aufzurufen.

Aber egal, so zum Spaß: Zeichne Dir mal ein Makro in Deine "Persönliche Arbeitsmappe" auf, dann öffne den VBA Editor und kopiere den Code unten in das Codemodul "DieseArbeitsmappe" der Datei "PERSONAL.XLSB".

Speichern Excel zu, wieder öffnen und eine neue Tabelle erstellen.

Andreas.

Option Explicit

Dim WithEvents App As Application

Private Sub App_NewWorkbook(ByVal Wb As Workbook)

MsgBox "Neue Datei " & Wb.Name

End Sub

Private Sub App_WorkbookNewSheet(ByVal Wb As Workbook, ByVal Sh As Object)

MsgBox "Neue Tabelle " & Sh.Name & " in " & Wb.Name

End Sub

Private Sub Workbook_Open()

Set App = Application

End Sub

Vielen Dank für die schnelle Antwort!

Wenn ich den Artikel richtig verstanden habe, könnte ich also ein Makro erstellen und es beim Öffnen einer Arbeitsmappe automatisch ausführen lassen. Das würde meinen ersten Fall komplett abdecken und für alle Tabellen in einer alten Datei würde eine Kopfzeile
definiert werden.

Ist es auch möglich ein Makro an das Erstellen einer Tabelle zu knüpfen? Ansonsten würden neu hinzugefügte Tabellen nicht automatisch eine Kopfzeile erhalten.

Eine Möglichkeit die mir einfallen würde, wäre es ein Makro zu erstellen, dass eine Tabelle erzeugt und die Kopfzeile gleich konfiguriert. Bei diesem Ansatz sehe ich aber die Problematik, dass er sehr leicht zu übersehen bzw. unabsichtlich zu umgehen ist.
Darum wäre mir ein Automatismus am liebsten (, der an das Ereignis der Erstellung gekoppelt ist).

Mit freundlichen Grüßen

kann man eine Art "Skript" erstellen, das entweder beim Öffnen einer Datei alle Tabellen mit einer Kopfzeile versieht oder beim Erzeugen einer neuen Tabelle der speziellen Tabelle eine Kopfzeile hinzufügt?

Kann man, nennt sich Makro, kannst Du Dir selber in Deine Persönliche Makroarbeitsmappe aufzeichnen und dann bei Bedarf ausführen.

https://support.office.com/de-de/ar...eichnung-974ef220-f716-4e01-b015-3ea70e64937b

Andreas.