Excel 2013: Werte schriftlich interpolieren ohne Graph

Meinst du, es gibt eine Möglichkeit, die ursprüngliche Tabelle zu "durchsuchen" und die interpolierten Werte direkt in die neue Tabelle zu überführen?

Ja, mit einem Makro lässt sich das problemlos machen.

EDIT:

Schau mal in diese Datei, ich denke das sollte ausreichen.

https://www.dropbox.com/s/fafglx771nol22t/cf7e40d4-49c3-4d5d-bb8c-380c443729ec.xlsm?dl=1

Andreas.

Andreas!

Das falsche Modul war die Lösung! Ich hab (wie oben beschrieben) das Code-Fenster mit Rechtsklick->Code anzeigen geöffnet. Dann hat sich ein Code-Fenster mit dem Titel "Tabelle1 (Code)" geöffnet. Das interessiert natürlich niemanden, denn "Modul1" ist das
richtige Fenster, aber immerhin hat sich dadurch der VB Editor geöffnet. Nachdem ich den Code da eingefügt habe, hat es astrein funktioniert. Die Werte werden perfekt interpoliert und normiert! Ganz große Klasse!

Vielen Dank nochmal für deine umfangreiche Hilfe! Das hat mir Stunden, wenn nicht sogar Tage geschenkt (da ich überhaupt nicht im Thema stehe ).

Ich hoffe, dieser Thread und deine Lösung können noch vielen anderen Usern hier kostbare Zeit sparen!

Beste Grüße aus einem nun etwas kühleren Büro,

nachdem ich den Code sorgfältig in den Editor verfrachtet habe, wollte ich über "=IPL" die Funktion aufrufen, aber weder erscheint dann die Autovervollständigung, noch funktioniert es,

Dann ist der Code im falschen Modul. Hast Du über Einfügen \ Modul ein reguläres Modul hinzugefügt?

Alternativ, kannst Du auf OneDrive zugreifen?

https://1drv.ms/x/s!AsEpmlJLteash3n3dXhsFQbnoBtK?e=G6PQpV

Wenn das auch nicht hilft, kann man Dir per Mail Dateien zuschicken?

Andreas.

Ja klar, das geht.

Klicke mit der rechten Maustaste auf die Blattregisterkarte

Wähle "Code anzeigen"

Klick im Menü auf Einfügen \ Modul

Füge den Code unten ein

Schließe den VBA-Editor

Ich habe jetzt 2 Tabellen formatiert und diese Formel benutzt, das geht natürlich nur wenn Du die gleichen Tabellennamen und Überschriften hast.

F2: =IPL([@Zeit];Tabelle1[Sensor 1 ];Tabelle1[Messzeit (s)])

Daher wandel ich die Formel mal auf normale Zellbezüge um, runter und nach rechts ziehen:

F2: =IPL($E2;$B$2:$B$6;$A$2:$A$6)

Alles klar? Falls nicht, kannst Du auf OneDrive zugreifen?

Andreas.

Option Explicit

Function IPL(ByVal X, Yvalues As Range, Xvalues As Range)

 Dim Xa, Ya, Xb, Yb

 Dim i As Long

 Xa = Xvalues.Value

 Ya = Yvalues.Value

 Xb = Array()

 Yb = Array()

 For i = 1 To UBound(Xa)

 If Not IsEmpty(Ya(i, 1)) Then

 ReDim Preserve Xb(0 To UBound(Xb) + 1)

 ReDim Preserve Yb(0 To UBound(Yb) + 1)

 Xb(UBound(Xb)) = Xa(i, 1)

 Yb(UBound(Yb)) = Ya(i, 1)

 End If

 Next

 IPL = InterpolateLinear(X, Xb, Yb, ScaleBeyondEdges:=True)

End Function

Function InterpolateLinear(ByVal X As Double, ByVal Xvalues, ByVal Yvalues, _

 Optional ByVal Count As Long = 1, Optional ByVal Interval As Variant, _

 Optional ByVal ScaleBeyondEdges As Boolean = False) As Variant

 'Returns an array 1..Count of double with interpolated Y values

 ' Xvalues and Yvalues must be an one dimensional array same size with numerical values

 ' Xvalues must be unique and in ascending or descending order

 ' Interval is a number, optional with a char in front to interpolate dates:

 ' y=Year, q=Quarter, m=Month, w=Week, d=Day, h=Hour, n=Minute, s=Second

 Dim i As Long, j As Long, l As Long, h As Long

 Dim Data() As Double

 Dim a As Double, b As Double, Increment As Double

 Dim Order As Boolean

 If IsMissing(Interval) Then

 Interval = 0

 Increment = 0

 ElseIf VarType(Interval) = vbString Then

 On Error Resume Next

 Increment = CDbl(Mid$(Interval, 2))

 On Error GoTo 0

 If Increment = 0 Then Increment = 1

 Interval = LCase(Left$(Interval, 1))

 Select Case Interval

 Case "y": Interval = "yyyy"

 Case "w": Interval = "ww"

 End Select

 Else

 Increment = Interval

 End If

 If Count <= 0 Then

 InterpolateLinear = Array()

 Exit Function

 End If

 ReDim Data(1 To Count) As Double

 l = LBound(Xvalues)

 h = UBound(Xvalues)

 Order = Xvalues(l) < Xvalues(h)

 For j = 1 To Count

 If X < Xvalues(l) = Order Then

 'Hunt down

 i = 1

 Do

 l = l - i

 If l <= LBound(Xvalues) Then

 l = LBound(Xvalues)

 Exit Do

 End If

 If X > Xvalues(l) = Order Then Exit Do

 i = i * 2

 Loop

 ElseIf X > Xvalues(h) = Order Then

 'Hunt up

 i = 1

 Do

 h = h + i

 If h >= UBound(Xvalues) Then

 h = UBound(Xvalues)

 Exit Do

 End If

 If X < Xvalues(h) = Order Then Exit Do

 i = i * 2

 Loop

 End If

 'We will find the right place in the table by means of bisection

 Do While h - l > 1

 i = (h + l) / 2

 If X > Xvalues(i) = Order Then

 l = i

 Else

 h = i

 End If

 Loop

 'Limit the scale at edges?

 If Not ScaleBeyondEdges Then

 If Order Then

 'Ascending

 If X < Xvalues(l) Then

 'Beyond the lower limit

 Data(j) = Yvalues(l)

 GoTo NextX

 End If

 If X > Xvalues(h) Then

 'Beyond the upper limit

 Data(j) = Yvalues(h)

 GoTo NextX

 End If

 Else

 If X > Xvalues(l) Then

 Data(j) = Yvalues(l)

 GoTo NextX

 End If

 If X < Xvalues(h) Then

 Data(j) = Yvalues(h)

 GoTo NextX

 End If

 End If

 End If

 'Calculate the linear value

 b = (Yvalues(h) - Yvalues(l)) / (Xvalues(h) - Xvalues(l))

 a = Yvalues(h) - b * Xvalues(h)

 Data(j) = a + b * X

NextX:

 If VarType(Interval) = vbString Then

 X = DateAdd(Interval, Increment, X)

 Else

 X = X + Increment

 End If

 Next

 InterpolateLinear = Data

End Function

Fangen wir mal ganz einfach an wir separieren die Sensoren und entfernen die Leerzeilen und haben Spalte A:B





Dann schreiben wir die gewünschten Zeiten in Spalte D und rechnen mal.

Das Problem ist das Deine Daten insgesamt keinen linearen Verlauf haben, also müssen wir die richtigen Zeitpunkte und Messwerte für den zu schätzenden Zeitpunkt nehmen.

E2: =SCHÄTZER(D2;$B$2:$B$3;$A$2:$A$3)

E3: =SCHÄTZER(D3;$B$2:$B$3;$A$2:$A$3)

E4: =SCHÄTZER(D4;$B$3:$B$4;$A$3:$A$4)

E5: =SCHÄTZER(D5;$B$3:$B$4;$A$3:$A$4)

E6: =SCHÄTZER(D6;$B$3:$B$4;$A$3:$A$4)

E7: =SCHÄTZER(D7;$B$3:$B$4;$A$3:$A$4)

Man kann sich sicherlich einen Formelkonstrukt mit VERGLEICH INDEX BEREICH.VERSCHIEBEN als Matrixformel basteln um die richtigen Werte für den Schätzer zu holen... aber bei dem Wetter, muss das sein?

Andreas.