Excel VBA: sichtbare Zeilen aus Excel Filter löschen

ITRookie55 · 3. Dezember 2020

Hallo zusammen

Ich habe ein Excel mit ca. 5000 Zeilen und 10 Spalten mit Überschriften. Ich setzte dann einen Filter und selektiere nach gewissen Kriterien. Diese Filterergebnisse möchte ich löschen. Nachstehendes VBA Skript löscht die angezeigten Zeilen, leider aber auch die Kopfzeile mit den Überschriften:

Sub SichtbaresLoeschen

If Sheets1.Rows.Height <> 0 Then Rows.Delete

End Sub

Wie muss ich das anpassen, dass die Kopfzeile bestehen bleibt?

Danke Gruss

5e5f8ac3-e583-482a-9

Hallo zusammen

Konnte es lösen:

Sub SichtbaresLoeschen()

Sheets(1).Rows("2:65536").Select

Selection.Delete Shift:=xlUp

End Sub

Andreas Killer

Option Explicit

Sub Test()

Dim R As Range

Set R = GetAutoFilterRange(ActiveSheet)

If Not R Is Nothing Then R.EntireRow.Delete

End Sub

Function GetAutoFilterRange(Optional ByVal Parent As Object, _

Optional WithoutHeader As Boolean = True) As Range

'Returns the visible range of an Autofilter, Excel 2010 and above

' Parent can be a Worksheet, ListObject or Range object

Dim R As Range

'Prepare

If Not Prepare(Parent) Then Exit Function

If Not AutoFilterMode(Parent) Then Exit Function

With Parent.AutoFilter

'Get the whole range

Set R = .Range

'Remove headings?

If WithoutHeader Then

If R.Rows.Count = 1 Then Exit Function

Set R = R.Resize(R.Rows.Count - 1).Offset(1)

End If

'Filter active?

If .FilterMode Then

'Error's off, we get an error if no cells are visible

On Error GoTo ExitPoint

Set R = R.SpecialCells(xlCellTypeVisible)

End If

End With

'Return the result

Set GetAutoFilterRange = R

ExitPoint:

End Function

Private Function Prepare(ByRef Parent As Object) As Boolean

'Returns the object that contains the Autofilter from the given object (Worksheet, ListObject or Range)

If Parent Is Nothing Then

If ActiveCell Is Nothing Then Exit Function

If ActiveCell.ListObject Is Nothing Then

Set Parent = ActiveSheet

Else

Set Parent = ActiveCell.ListObject

End If

ElseIf TypeOf Parent Is Range Then

If Parent.ListObject Is Nothing Then

Set Parent = Parent.Parent

Else

Set Parent = Parent.ListObject

End If

End If

Prepare = Not Parent Is Nothing

End Function

Private Function AutoFilterMode(ByRef Parent As Object) As Boolean

'True if Parent has an Autofilter

If TypeOf Parent Is Worksheet Then

AutoFilterMode = Parent.AutoFilterMode

ElseIf TypeOf Parent Is ListObject Then

AutoFilterMode = Not Parent.AutoFilter Is Nothing

End If

End Function

5e5f8ac3-e583-482a-9

Hallo Andreas

Danke für Deine Hilfe, habe jetzt Deine Version genommen. Beste Grüsse

Andreas Killer

Hallo zusammen

Konnte es lösen:

Wenn Du meinst das über 30 Jahre Erfahrung im Programmieren nutzlos sind und Du es besser kannst...

Wir sprechen uns wieder nachdem Du damit Schiffbruch erlitten hast. ;-)

Ich kann nur eindringlich davon abraten!

Andreas.

Claus Busch

Hallo Chris,

liest du die Fragen durch bevor du antwortest?

Moya will keine laufende Summe sondern die Wochenarbeitszeit.

Auch in diesem Thread:

http://answers.microsoft.com/de-de/...rchgehen/2b553169-2644-431a-8018-54da6c2ee074

ist deine Antwort voll daneben, denn es geht um sichtbare Zellen in einer gefilterten Liste.

Bitte korrigieren oder Antworten löschen.

Claus

Hi,

willkommen im Windows Forum!

Excel VBA: sichtbare Zeilen aus Excel Filter löschen - Similar Threads - Excel VBA sichtbare	Forum	Datum
excel in word, anzahl der sichtbaren Zeilen excel in word, anzahl der sichtbaren Zeilen: Hallo Community,ich habe eine Excel-Tabelle mit sagen wir mal 10 Zeilen in word eingebunden. Jetzt öffne ich die Tabelle und füge zwisschen Zeile 3 und Zeile 4 eine Zeile dazu. Zeile 10 wird zu...	Microsoft Office	19. Juli 2022
Excel Zeilen auslesen mit Filter auf Werte in einer Spalte Excel Zeilen auslesen mit Filter auf Werte in einer Spalte: Hallo,ich möchte eine Excelliste 500 Zeilen mit einer Tabelle einlesen, aber nur wenn einer Spalte ein Wert n oder i steht. Aber in dieser Spalte stehen auch Zahlen, Datum, nichts... usw.Ich...	Microsoft Office	15. April 2022
Excel/VBA Zeile am oberen Bildschirmrand Excel/VBA Zeile am oberen Bildschirmrand: Hallo,ich möchte eine bestimmte Zeile innerhalb einer langen Tabelle mittels VBA-Prozedur an den oberen Bildschirmrand bringen.Wie kann ich das machen?Gibt's dafür einfache Anweisungen?Danke und...	Microsoft Office	12. Dezember 2021
Excel: nach Filter löschen nicht am Tabellenanfang landen Excel: nach Filter löschen nicht am Tabellenanfang landen: Guten Tag,ich habe eine einfache Tabelle ohne Makros oder Formeln. Sie umfaßt etwa 2000 Zeilen und 15 Spalten. Dort möchte ich nun über die Filterfunktion nur ein Filter zB in Spalte B...	Microsoft Office	23. Mai 2021
Tausende von Zeilen in Excel verschwunden und nicht wieder sichtbar zu machen Tausende von Zeilen in Excel verschwunden und nicht wieder sichtbar zu machen: Bei Eingabe von Daten in Excel, habe ich bemerkt, dass ich plötzlich in Zeilennummer 1048531 eingebe, obwohl die vorhergehenden Eingaben bei Zeilennummer 15900 und nochwas waren. Zwischen den...	Microsoft Office	24. September 2020
Filter soll nicht die ganze Zeile "löschen" Filter soll nicht die ganze Zeile "löschen": Guten Tag, ich stecke leider in einer zwickmühle... Kurze beschreibung meines Problems: Ich habe 2 Tabellen mit Filtern in einer Mappe. (Insgesamt 7 Mappen für 7 Standorte) Tabelle 1 =...	Microsoft Office	24. Juli 2019
Makro in Excel soll bestimme Zeilen löschen, oberste Zeile aber nicht Makro in Excel soll bestimme Zeilen löschen, oberste Zeile aber nicht: Hallo, ich mache meine ersten VBA-Versuche und scheitere nun bei einer Kleinigkeit, wie ich denke, aber ich finde das Problem einfach nicht. Ich möchte in einer Excel-Tabelle Zeilen löschen,...	Microsoft Office	19. September 2017

Excel VBA: sichtbare Zeilen aus Excel Filter löschen