Falscher Inhaltsverzeichniseintrag durch Feldfunktion

Hallo Alvar,

das Problem entsteht, weil Word - warum auch immer - innerhalb der Feldfunktion eine (verborgene) Textmarke erstellt, auf die das Inhaltsverzeichnis Bezug nimmt. Du müsstest also manuell oder automatisch per Makro die überflüssigen
Einträge im Inhaltsverzeichnis löschen.

Alternativ kannst du das folgende von meinem MVP-Kollegen Paul Edstein (https://mvp.microsoft.com/de-de/PublicProfile/33619?fullName=Paul Edstein)
stammende Bedingungsfeld testen:

{ AUTOTEXT { If { DOCPROPERTY Abteilung } = "A1" "Mein Baustein" "Absatzmarke" } }

Voraussetzung: Du integrierst in den AutoText-Eintrag eine führende, z. B. mit "Standard" formatierte Absatzmarke. Und im Bedingungsfeld musst du dort, wo jetzt die Zeichenfolge
Absatzmarke steht, tatsächlich eine Absatzmarke einfügen, also die Eingabetaste drücken.

Das Bedingungsfeld beinhaltet also, dass sowohl zu Beginn als auch am Ende eine zusätzliche Absatzmarke eingefügt wird. Entsprechend sollte sich das Bedingungsfeld nicht in einem eigenen Absatz, sondern im Fließtext befinden.

Viele Grüße

Lisa

Hallo Lisa,

danke für Deine Nachfrage.

Das Dokument besteht aus mehreren gegliederten Absätzen, also Überschriften 1 bis n. Diese sind bereits nummeriert durch . Dazwischen sind Standard-Absätze. An einer beliebigen Stelle nach einem Standard-Absatz soll also nun ein Autotext-Baustein eingefügt
werden, um die Gliederung zu erweitern.

Der Feldausdruck { IF { DOCPROPERTY "Abteilung" } = "A1" { AUTOTEXT "MeinBaustein" } "Alternativtext" } steht am Anfang des Absatzes, oder besser, der gesamte Absatz besteht nur aus diesem Feldausdruck.

Wenn die Bedingung erfüllt ist, wird der Autotext-Baustein eingefügt. Dieser enthält zwei oder mehr Absätze: Der erste ist als Überschrift 3 formatiert, der zweite (bzw. der gesamte Rest) als Standardtext.

Das funktioniert so auch ganz prächtig, nur leider verhält sich das Inhaltsverzeichnis am Dokumentanfang wie beschrieben fehlerhaft.

Viele Grüße,

Alvar

Hallo,

du hast das Feld am Anfang eines Standard-Absatzes eingefügt? Du willst, dass bei erfüllter Bedingung an dieser Stelle ein nummerierter Absatz eingefügt wird? Andernfalls soll nichts angezeigt werden, bzw. der Standardabsatz soll bestehen bleiben?

Es geht nicht darum, einem bereits nummerierten Absatz einen weiteren hinzuzufügen?

Viele Grüße

Lisa

Vielen Dank für eure Vorschläge!

Mittlerweile habe ich eine andere Lösung, die auch im Hinblick auf die Pflege der Textbausteine besser ist.

Ich sammle die Textbausteine ohne Nummerierung in einem separaten Dokument (Textbausteine.docx) und versehe sie mit Textmarken ("TBTextmarke").

Diese füge ich mit { IF { DOCPROPERTY "Abteilung" } = "A1" { INCLUDETEXT Pfad zu Textbausteine.docx
TBTextmarke } "Alternativtext" } in das Ziel-Dokument ein.

Da nun die Nummerierung über alle Überschriften/Listeneinträge nicht stimmt, korrigiere ich sie mit Hilfe eines Makros:

Sub Nummerieren()

Dim oToc As TableOfContents

Dim oDoc As Document

Dim oPar As Paragraph

Dim lfTemp As ListFormat

Dim ltTemp As ListTemplate

Dim flTemp As Field



Set oDoc = ActiveDocument

Set oToc = oDoc.TablesOfContents(1)



' Feld-Ergebnisse in normalen Text umwandeln <-- wichtig, damit die ListTemplate-Zuweisung ausschließlich

' den Überschrift-Absatz betrifft!

For Each flTemp In oDoc.Fields

If flTemp.Type <> wdFieldTOC And flTemp.Type <> wdFieldTOCEntry Then

flTemp.Unlink

End If

Next flTemp



' Nicht nummerierte Überschriften suchen und nummerieren

For Each oPar In oDoc.Paragraphs

If oPar.OutlineLevel <> wdOutlineLevelBodyText Then

Set lfTemp = oPar.Range.ListFormat

If lfTemp.ListTemplate Is Nothing Then

'Selection.StartOf Unit:=wdParagraph, Extend:=wdMove

lfTemp.ApplyListTemplateWithLevel ListTemplate:=ltTemp, ContinuePreviousList:=True, ApplyTo:=wdListApplyToSelection, DefaultListBehavior:=wdWord10ListBehavior

ElseIf ltTemp Is Nothing Then

Set ltTemp = lfTemp.ListTemplate

End If

End If

Next oPar



'Update TOC

oToc.Update



Set oDoc = Nothing

Set oToc = Nothing

End Sub

Das Objektmodell von Word ist schon echt schräg! Entsprechend schräg verhält sich Word auch manchmal ;-)

Schönen Gruß,

Alvar

Hi Alvar,

No doubt that the solution suggested by Paul Edstein (posted by Lisa) is good since it makes the problem go away.

I have created a macro that can be used as an alternative. The macro does not fix the problems within the AutoText fields but it fixes the problem in the table of contents (TOC). The macro below assumes that only one
TOC is found in the document. The macro:

1. unlocks the TOC field
2. updates the TOC field (will bring the undesired paragraphs back in the TOC)
3. finds and deletes the undesired paragraphs in the TOC by examining the TOC bookmarks that the hyperlinks in the TOC point to
4. locks the TOC field

Further details are included in comments in the macro below.

------------------MACRO START-----------------

Sub UpdateTOC_RemoveFakeItemsFromTOC()

'Fake items are paragraphs with hyperlinks to TOC bookmarks

'that are erroneously added at the end of the field code of AutoText fields that insert a numbered paragraph via a conditional field construction

Dim oToc As TableOfContents

Dim oDoc As Document

Dim oHL As Hyperlink

Dim lngDeleted As Long

Const cstrTitle As String = "Update TOC and Remove Fake Items From TOC"

If ActiveDocument.TablesOfContents.Count = 0 Then

MsgBox "No TOC found in document.", vbOKOnly, cstrTitle

Exit Sub

End If

Set oDoc = ActiveDocument

Set oToc = oDoc.TablesOfContents(1)

lngDeleted = 0

Application.ScreenUpdating = False

'Unlock TOC field if locked - TOC field itself is first field, hyperlink fields come after

oToc.Range.Fields(1).Locked = False

'Update TOC

oToc.Update

'Check all hyperlinks in TOC - if length of bookmarked range the hyperlink points to is an empty string

'then delete the paragraph with that hyperlink from the TOC

For Each oHL In oToc.Range.Hyperlinks

If oDoc.Bookmarks(oHL.SubAddress).Range.Text = "" Then

oHL.Range.Paragraphs.First.Range.Delete

lngDeleted = lngDeleted + 1

End If

Next oHL

'Lock TOC

oToc.Range.Fields(1).Locked = True

Application.ScreenUpdating = False

Application.ScreenRefresh

MsgBox "Finished updating TOC. " & lngDeleted & " paragraphs with fake references deleted. The TOC field has been locked.", vbOKOnly, cstrTitle

Set oDoc = Nothing

Set oToc = Nothing

End Sub

------------------MACRO END-----------------