Formel "=DATEDIF" nicht möglich, was kann man tun?

Hallo Andreas,

so perfekt ist das nicht. Das ist ein Fehler drin und die Formel rechnet nur innerhalb des gleichen Jahres korrekt. Wenn die Differenz mehr als 1 Jahr ist, probiere es so:

=DATEDIF(A1;B1;"m") für die Monate

=DATEDIF(A1;B1;"md") für die Tage

=DATEDIF(A1;B1;"m")&" Monate "&DATEDIF(A1;B1;"md")&" Tage " zusammengefasst.

Mit freundlichen Grüßen

Claus

Hallo,

diese Funktion ist nicht aufgeführt.

Schreibe einfach die Formel =DATEDIF(...;...;...), das funktioniert.

Claus

Hallo Freddy,

durch die UND-Verknüpfung kommt der Leerstring nur wenn beide Zellen leer sind. Wenn nur eine Zelle leer ist, greift dies nicht und dann läuft DATEDIF in diesen Fehler, weil nur ein Datum vorhanden ist.

Ändere die Formel auf:

=WENN(ODER(ISTLEER(F5);ISTLEER(G5));"";DATEDIF(G5;F5;"d"))

oder einfacher, da keine Verknüpfung gebraucht wird:

=WENN(ANZAHL(F5:G5)<2;"";DATEDIF(G5;F5;"d"))

Claus

Hallo Andreas,

Excel hat die Funktion DateDif mit der du die Differenz zwischen zwei Datumswerten errechnen kannst.

A1 = Erstzulassungsdatum, B1 = Erstelldatum

=DATEDIF(A1;B1;"ym")

gibt dir die vollen Monate aus dieser Zeitspanne . Tage werden nicht berücksichtigt.

Wenn du die Monate aufrunden willst, wenn die Differenz mehr als die vollen Monate beträgt, dann probiere es so:

=DATEDIF(A1;B1;"ym")+(DATEDIF(A1;B1;"md")>0)

Bei einer Differenz von 10 Monaten und 2 Tagen würde diese Formel dann auf 11 Monate aufrunden.

Ganz genau kannst du es dann so errechnen:

=DATEDIF(A1;B1;"ym")&" Monate "&DATEDIF(A1;B1;"md")&" Tage "

Edit: Das Argument "Y" berechnet die vollen Jahre, "M" die vollen Monate, "D" die Tage, "MD" die Tage zwischen Start- und Enddatum ohne die Monate und die Jahre, "YM" die Monate ohne die Tage,
"YD" die Tage ohne die Jahre.

Mit freundlichen Grüßen

Claus

Hallo,

DateDif erwartet als Argumente Datumswerte und keine Strings.

Deine Formel sollte also so lauten:

=DATEDIF(DATWERT("04.12.2015");DATWERT("31.12.2015")+1;"md")

Wenn du nur Tage berechnen willst, kannst du einfach vom größeren Datum das kleiner abziehen und 1 addieren:

=DATWERT("31.12.2015")+1-DATWERT("04.12.2015")

Eine Alternative kannst du hier finden:

http://excelformeln.de/formeln.html?welcher=141

Claus