IF Funktion + INDEX, MATCH

SHE Olga · 17. Juni 2019

Guten Tag,

ich muss IF Funktion alles auf ein mal so schreiben aber irgendwie fuktioniert es gar nicht obwohl wenn ich separat es probiere, dann geht es:

=IF($M6="LOCAL (One Country only)";INDEX('FIN SERV'!$DW$6:$HI$60;MATCH($C6;'FIN SERV'!$F$6:$F$60;0);MATCH(P$5;'FIN SERV'!$DW$6:$HI$6;0)));

IF($M6="GLOBAL";INDEX('FIN SERV'!$DW$6:$HI$60;MATCH($C6;'FIN SERV'!$DT$6:$DT$60;0);MATCH(P$5;'FIN SERV'!$DW$6:$HI$6;0)));

IF(OR($M6="RG DACH";$M6="RG Baltic"; "RG UK & IE";$M6="RG RU & UA");INDEX('FIN SERV'!$DW$6:$HI$60;MATCH($C6;'FIN SERV'!$DU$6:$DU$60;0);MATCH(P$5;'FIN SERV'!$DW$6:$HI$6;0));

INDEX('FIN SERV'!$DW$6:$HI$60;MATCH($C6;'FIN SERV'!$DV$6:$DV$60;0);MATCH(P$5;'FIN SERV'!$DW$6:$HI$6;0))

Geht es überhaupt mit IF funktion so viel?

Vielen Dank!

Liebe Grüße,

Olga

Claus Busch

Hallo Olga,

das würde schon gehen, aber du hast die Klammern falsch gesetzt.

Außerdem kann man die Formel vereinfachen, da der INDEX immer gleich bleibt und die WENN-Verzweigung nur für die Zeilen gilt:

=INDEX('FIN SERV'!$DW$6:$HI$60,IF(M6="LOCAL (One Country only)",MATCH($C6,'FIN SERV'!$F$6:$F$60,0),IF(M6="GLOBAL",MATCH($C6,'FIN SERV'!$DT$6:$DT$60,0),IF(OR(M6={"RG DACH";"RG BALTIC";"RG RU & UA"}),MATCH($C6,'FIN SERV'!$DU$6:$DU$60,0),MATCH($C6,'FIN SERV'!$DV$6:$DV$60,0)))),MATCH(P$5,'FIN
SERV'!$DW$6:$HI$6,0))

Deine Formel müsstest du wegen der Klammern so ändern:

=IF($M6="LOCAL (One Country only)",INDEX('FIN SERV'!$DW$6:$HI$60,MATCH($C6,'FIN SERV'!$F$6:$F$60,0),MATCH(P$5,'FIN SERV'!$DW$6:$HI$6,0)),

IF($M6="GLOBAL",INDEX('FIN SERV'!$DW$6:$HI$60,MATCH($C6,'FIN SERV'!$DT$6:$DT$60,0),MATCH(P$5,'FIN SERV'!$DW$6:$HI$6,0)),

IF(OR($M6="RG DACH",$M6="RG Baltic", "RG UK & IE",$M6="RG RU & UA"),INDEX('FIN SERV'!$DW$6:$HI$60,MATCH($C6,'FIN SERV'!$DU$6:$DU$60,0),MATCH(P$5,'FIN SERV'!$DW$6:$HI$6,0)),

INDEX('FIN SERV'!$DW$6:$HI$60,MATCH($C6,'FIN SERV'!$DV$6:$DV$60,0),MATCH(P$5,'FIN SERV'!$DW$6:$HI$6,0)))))

Claus

Claus Busch

Hallo Olga,

die Formel lässt sich noch ein wenig vereinfachen:

=INDEX('FIN SERV'!$DW$6:$HI$60;MATCH(C6;IF(M6="LOCAL (One Country only)";'FIN SERV'!$F$6:$F$60;IF(M6="GLOBAL";'FIN SERV'!$DT$6:$DT$60;IF(OR(M6={"RG DACH";"RG BALTIC";"RG RU & UA"});'FIN SERV'!$DU$6:$DU$60;'FIN SERV'!$DV$6:$DV$60)));0);MATCH(P$5;'FIN SERV'!$DW$6:$HI$6;0))

Claus

SHE Olga

Danke sehr für diese super Hinweis!

SHE Olga

Vielen Danke schön! Jetzt funktioniert

Chris-Kaiser

Hallo Dorothee,

anbei eine alternative Lösung mit Index.

ggf. würde diese auch einen Intervall ausgeben wenn nicht mit Null abgeschlossen wird, falls es mal nötig sein sollte.

Formel in C2

=IF(OR(B2=0,B1>0),"",IFERROR(INDEX(A2:A999,MATCH(0,B2:B999,0)-1),INDEX(A:A,MATCH(-9^9,B:B,-1)))-A2)

Wenn immer mit Null abgeschlossen wird könnte es auch so verwendet werden:

=IF(OR(B2=0,B1>0),"",INDEX(A2:A999,MATCH(0,B2:B999,0)-1)-A2)

Demodatei

lg

Chris

p.s wie ich in deinem Screensh. sehe hast du ; als Trenner dann die , durch Strichpunkt ersetzten oder einfach aus der Datei die Formel kopieren.

Hi,

willkommen im Windows Forum!

IF Funktion + INDEX, MATCH - Similar Threads - Funktion INDEX MATCH	Forum	Datum
Syntax der Funktion IF in einer Word-Tabelle Syntax der Funktion IF in einer Word-Tabelle: Hallo, ich bitte für folgende Aufgabe um HilfeIn einer Word-Tabelle A1:C10 soll das Feld C1 berechnet werden:- sind alle Felder von B1 bis B10 leer, dann bleibt auch das Feld C1 leer.- stehen...	Microsoft Office	7. März 2025
If Funktion in Word If Funktion in Word: Hallo zusammen,ich habe ein Problem mit der IF-Funktion in Word.Ich lasse aus einer Fachanwendung heraus Formulare mit Textbausteinen generieren.Jetzt stoße ich auf folgendes Problem.Wohnt ein...	Microsoft Office	8. Juli 2024
IF Funktion in Word IF Funktion in Word: Hallo zusammen,ich habe ein Dokument als .rtf erzeugt in welchem ich Kopfdaten automatisch befüllen lasse.Nun gibt es Felder welche nicht immer gefüllt sind. Sind diese nicht gefüllt wird eine...	Microsoft Office	7. Juni 2024
Wie Dropdown-Inhaltssteuerelement mit IF-Funktion verbinden? Wie Dropdown-Inhaltssteuerelement mit IF-Funktion verbinden?: Hallo, Ich möchte ein Dropdownmenü für Adressen einfügen, da Dropdowneinträge nicht mehrzeilig sein können will ich das Dropdown mit einer IF-Funktion verknüpfen, die dann, wenn die richtige Firma...	Microsoft Office	12. Januar 2023
Zeitvergleich Index und Vergleich Funktionen Zeitvergleich Index und Vergleich Funktionen: Hallo zusammen, ich hoffe hier hat jemand eine Idee, meine Suche im Internet war hier bisher erfolglos. Ich habe eine Tabelle mit eine Spalte in der Uhrzeiten im 15 Minuten Intervall von 00:00...	Microsoft Office	17. Februar 2021
Word IF-Funktion Word IF-Funktion: Hallo, ich versuche in einer Tabelle die "IF-Funktion" einzubauen und erhalte mit >Alt+F9< die Meldung "!Syntaxfehler, " Beispiel Funktion: =IFA1 > 70, 1, 0. Frage: was ist an dieser Eingabe...	Microsoft Office	6. Februar 2021
#Value error INDEX MATCH multiple search with rows and columns #Value error INDEX MATCH multiple search with rows and columns: Good day, dear all, I am struggling to understand why my formula is not working. Tried using CTRL + SHIFT + ENTER but it still doesn't work. {=INDEX('FIN SERV'!$CQ7:$EY60;MATCH(P$5;'FIN...	Microsoft Office	14. Juni 2019

IF Funktion + INDEX, MATCH