Suche liefert kein Ergebniss oder unkomplettes Ergebniss

RalfGlaesser · 6. März 2017

Hallo,

bei meinem Suchmakro bekomme ich kein Suchergebniss bzw. nicht nachvollziehbar ein nur Teilergebniss.

Woran könnte das liegen:

Hier das Makro

Sub Suchen()
'Start der Suchfunktion
Suchen:
Dim Anz As Long, a As Long, SuchIN As Range
Dim SuReNr As String, Zelle As Range
ActiveSheet.Range("E2:E500").Interior.ColorIndex = xlNone
SuReNr = InputBox("Rechnungsnummer eingeben", "Rechnungsnummer")
If SuReNr = "" Then
Exit Sub
End If
'Suche in allen Zellen
b = 0
Set SuchIN = ActiveSheet.Cells
'Zähle Zellen mit der Rechnungsnummer
Anz = Application.WorksheetFunction.CountIf(SuchIN, "*" & SuReNr & "*")
With SuchIN
For a = 1 To Anz
If a = 1 Then
'Suche erste
Set Zelle = .Find(what:="*" & SuReNr & "*", _
After:=Cells(5, 1), _
LookIn:=xlValues)
SuReNr = Zelle.Address & Chr(13)
Zelle.Interior.ColorIndex = 6
Else
'Suche nächste
Set Zelle = .FindNext(Zelle)
Zelle.Interior.ColorIndex = 6
SuReNr = SuReNr & Zelle.Address & Chr(13)
End If
b = 1
Next a
End With
Set Zelle = Nothing
Set SuchIN = Nothing
'Ergebniss anzeigen
If b = 1 Then
MsgBox "Die Nummer wurde in: " & (Chr(13)) & SuReNr & (Chr(13)) & _
"gefunden und markiert!"
Else
MsgBox "Rechnungsnummer " & SuReNr & " nicht gefunden!"
End If
'Nächste Rechnungsnummer suchen
SuReNrNeu:
If MsgBox(prompt:="Noch eine Rechnungsnummer suchen?", Buttons:=vbYesNo + vbQuestion) = vbYes Then
GoTo Suchen
End If
End Sub

Claus Busch

Hallo Ralf,

wenn ich das richtig sehe, sind deine Rechnungsnummern nur in Spalte E. Warum sonst entfärbst du nur diesen Bereich?

Probiere es mal so:

Sub Suche()

Dim c As Range

Dim Ant As Integer, i As Integer

Dim varFund() As Variant

Dim SuReNr As String, FirstAddress As String, strOut As String
SuReNr = InputBox("Rechnungsnummer eingeben", "Rechnungsnummer")

If SuReNr = "" Then Exit Sub
With ActiveSheet.Range("E2:E500")

    .Interior.ColorIndex = xlNone

    Set c = .Find(SuReNr, LookIn:=xlValues, lookat:=xlWhole)

    If Not c Is Nothing Then

        FirstAddress = c.Address

        Do

            c.Interior.Color = vbYellow

            ReDim Preserve varFund(i)

            varFund(i) = c.Address(0, 0)

            i = i + 1

            Set c = .FindNext(c)

        Loop While Not c Is Nothing And c.Address <> FirstAddress

    End If

End With
If i > 0 Then

    strOut = Join(varFund, Chr(10))

    MsgBox "Suchnummer wurde gefunden und Zellen wurden eingefärbt in" _

        & Chr(10) & strOut

Else

    MsgBox "Suchnummer ist nicht vorhanden"

End If

    

Ant = MsgBox("Noch eine Rechnungsnummer suchen?", vbYesNo + vbQuestion)

If Ant = vbYes Then Suche

End Sub


Claus

RalfGlaesser

Hallo Claus,

so geht das natürlich auch ;-)

Besten Dank

Gruss

Ralf

Claus Busch

Hallo Ralf,

das geht noch einfacher. Ändere xlWhole auf xlPart:

Set c = .Find(SuReNr, LookIn:=xlValues, lookat:=xlPart)

Claus

RalfGlaesser

Hallo Claus,

funktioniert fast. Trotzdem erstmal Danke.

Das Problem jetzt noch besteht darin, das in der Spalte "E" nicht nur allein die Rechnungsnummer steht, sondern dort noch andere Bestandteile von Buchungskennungen existieren. Die Rechnungsnummer ist nur ein Teil des Zellinhaltes.

Deshalb hatte ich auch das:

"*" & SuReNr & "*"

drin.

Gruss

Ralf

Habe so geändert....:

Set c = .Find("*" & SuReNr & "*", LookIn:=xlValues, lookat:=xlWhole)

Sollte so gehen, oder?

Gruss

Ralf

AxelHeubeck

Danke.

Hier der Link zum soeben eröffneten THread im TechNet:

https://social.technet.microsoft.com/Forums/de-DE/81f6d437-989f-4dfd-91be-f62942f96272/outlook-suche-liefert-keine-ergebnisse?forum=office_generalde

Hi,

willkommen im Windows Forum!

Suche liefert kein Ergebniss oder unkomplettes Ergebniss - Similar Threads - Suche liefert Ergebniss	Forum	Datum
OneDrive Suche findet keine Ergebnisse OneDrive Suche findet keine Ergebnisse: Seit einiger Zeit dürfte die Indizierung meines OneDrive-Accounts nicht mehr funktionieren. Eine Suche nach Dateinamen - die ich gleich auf der Startseite sehe - oder auch Suchen nach...	Microsoft Office	7. Juni 2025
OneDrive Web- und App-Suche liefert keine Ergebnisse Kontoindex defekt? OneDrive Web- und App-Suche liefert keine Ergebnisse Kontoindex defekt?: Ich nutze OneDrive privat mit meinem Microsoft-Konto und habe seit einiger Zeit das Problem, dass die Suche in OneDrive keine Ergebnisse mehr liefert, obwohl Dateien definitiv vorhanden sind. Die...	Microsoft Office	1. Juni 2025
Mail Suche bei Outlook für Mac liefert keine Ergebnisse Mail Suche bei Outlook für Mac liefert keine Ergebnisse: Liebe Community,ich habe folgendes Problem: bei der Suche nach mails im Posteingang liefert Outlook keine Ergebnisse, obwohl die Mails dort vorhanden sind. Outlook findet generell keine Mails die...	Outlook.com	7. Januar 2025
Onedrive Suche findet keine Ergebnisse Onedrive Suche findet keine Ergebnisse: Hi,bei mir ist die Suche sowohl über Browser als auch mit der Android App erfolglos. Das ist echt nervig. Die Synchronisation mit dem PC hingegen funktioniert und da werden auch die Dateien...	Microsoft Office	19. August 2022
Outlook Suche liefert keine Ergebnisse Outlook Suche liefert keine Ergebnisse: Hallo liebe Community, ich brauche Eure Hilfe. Bei einem Rechner funktioniert die Suche im Outlook nicht. Es wird folgende Meldung angezeigt, wenn man Etwas in die Suchleiste eintippt und die...	Microsoft Office	9. Juli 2020
Outlook: Suche liefert nach Update keine Ergebnisse mehr Outlook: Suche liefert nach Update keine Ergebnisse mehr: Hallo, leider hab ich keinen aktuellen Beitrag dazu gefunden bzw. keine der Tipps aus anderen Beitragen hat geklappt. Seit dem letzten Update von Outlook vor einigen Tagen (jetzt habe ich...	Microsoft Office	10. Januar 2019
Suche im öffentlichen Ordner liefert nicht alle betroffenen Ergebnisse Suche im öffentlichen Ordner liefert nicht alle betroffenen Ergebnisse: Liebe Community, ich habe das Problem, dass wenn ich in einem öffentlichen Ordner nach etwas Suche, mir nicht alle von der Suche betroffenen Ergebnisse angezeigt werden. Ich suche...	Microsoft Office	15. Oktober 2018

Suche liefert kein Ergebniss oder unkomplettes Ergebniss